sql数据库死锁怎么检测_sql数据库死锁检测语句

declare @kill_lock_spid bit=0, --是否杀掉死锁的进程,1 杀掉, 0 仅显示
@show_spid_if_nolock bit=1 --如果没有死锁的进程,是否显示正常进程信息,1 显示,0 不显示

declare @count int,@s nvarchar(1000),@i int

if object_id('tempdb..#t') is not null
drop table #t;

if object_id('tempdb..#t1') is not null
drop table #t1;

create table #t(
[id] [int] IDENTITY(1,1) NOT NULL,
[标志] [varchar](10) NOT NULL,
[进程ID] [smallint] NOT NULL,
[线程ID] [smallint] NOT NULL,
[块进程ID] [smallint] NOT NULL,
[数据库ID] [smallint] NOT NULL,
[数据库名] [nvarchar](128) NULL,
[用户ID] [smallint] NULL,
[用户名] [nvarchar](128) NOT NULL,
[累计CPU时间] [int] NOT NULL,
[登陆时间] [datetime] NOT NULL,
[打开事务数] [smallint] NOT NULL,
[进程状态] [nvarchar](128) NOT NULL,
[工作站名] [nvarchar](128) NOT NULL,
[应用程序名] [nvarchar](128) NOT NULL,
[工作站进程ID] [nvarchar](128) NOT NULL,
[域名] [nvarchar](128) NOT NULL,
[网卡地址] [nvarchar](128) NOT NULL
)

insert into #t
select 标志,
进程ID=spid,线程ID=kpid,块进程ID=blocked,数据库ID=dbid,
数据库名=db_name(dbid),用户ID=uid,用户名=loginame,累计CPU时间=cpu,
登陆时间=login_time,打开事务数=open_tran, 进程状态=status,
工作站名=hostname,应用程序名=program_name,工作站进程ID=hostprocess,
域名=nt_domain,网卡地址=net_address
from(
select 标志='死锁的进程',
  spid,kpid,a.blocked,dbid,uid,loginame,cpu,login_time,open_tran,
  status,hostname,program_name,hostprocess,nt_domain,net_address,
  s1=a.spid,s2=0
from master..sysprocesses a join (
  select blocked from master..sysprocesses group by blocked
  )b on a.spid=b.blocked where a.blocked=0
union all
select '|_牺牲品_>',
  spid,kpid,blocked,dbid,uid,loginame,cpu,login_time,open_tran,
  status,hostname,program_name,hostprocess,nt_domain,net_address,
  s1=blocked,s2=1
from master..sysprocesses a where blocked<>0
) a
order by s1,s2

select @count=@@rowcount,@i=1
if @count=0 and @show_spid_if_nolock=1
begin
insert #t
select 标志='正常的进程',
spid,kpid,blocked,dbid,db_name(dbid),uid,loginame,cpu,login_time,
open_tran,status,hostname,program_name,hostprocess,nt_domain,net_address
from master..sysprocesses

set @count=@@rowcount
end

if @count>0
begin
create table #t1(id int identity(1,1),a nvarchar(1024),b Int,EventInfo nvarchar(max))

if @kill_lock_spid=1
begin
declare @spid varchar(10),@标志 varchar(10)
while @i<=@count
begin
select @spid=进程ID,@标志=标志 from #t where id=@i

insert #t1 exec('dbcc inputbuffer('+@spid+')')

if @@rowcount=0 insert #t1(a) values(null)

if @标志='死锁的进程' exec('kill '+@spid)

set @i=@i+1
end
end
else
while @i<=@count
begin
select @s='dbcc inputbuffer('+cast(进程ID as varchar)+')' from #t where id=@i
insert #t1 exec(@s)
if @@rowcount=0 insert #t1(a) values(null)

set @i=@i+1
end

select a.*,进程的sql语句=b.EventInfo
from #t a
join #t1 b on a.id=b.id
order by 进程ID
end

drop table #t
drop table #t1